stockholm -> hrm

1 files changed, 31 insertions, 0 deletions

diff --git a/pkgs/haskell/default.nix b/pkgs/haskell/default.nix
new file mode 100644
index 0000000..7baaa89
--- /dev/null
+++ b/pkgs/haskell/default.nix
@@ -0,0 +1,31 @@
+let
+  overrides = { lib, mylib }: self: super:
+    mylib.mapNixDir (path: self.callPackage path {}) [
+      ./.
+    ] // {
+      xmonad-tv = self.callPackage ./xmonad-tv {
+        pager = self.desktop-pager;
+      };
+    };
+in
+  self: super: let
+    inherit (super) lib;
+    mylib = import ../../lib/pure.nix {
+      inherit lib;
+    };
+  in {
+    haskell = super.haskell // {
+      packages = lib.mapAttrs (name: value:
+        if builtins.hasAttr "override" value
+          then value.override (old: {
+            overrides =
+              lib.composeExtensions (old.overrides or (_: _: { })) (overrides { inherit lib mylib; });
+          })
+          else value
+      ) super.haskell.packages;
+    };
+    haskellPackages = super.haskellPackages.override (old: {
+      overrides =
+        lib.composeExtensions (old.overrides or (_: _: { })) (overrides { inherit lib mylib; });
+    });
+  }