add urxvtd service module

1 files changed, 48 insertions, 0 deletions

diff --git a/modules/urxvtd.nix b/modules/urxvtd.nix
new file mode 100644
index 0000000..ca21c62
--- /dev/null
+++ b/modules/urxvtd.nix
@@ -0,0 +1,48 @@
+{ config, lib, pkgs, ... }:
+
+with builtins;
+with lib;
+
+{
+  options = {
+    services.urxvtd = {
+      enable = mkOption {
+        type = types.bool;
+        default = false;
+        description = "Enable urxvtd per user";
+      };
+      users = mkOption {
+        type = types.listOf types.string;
+        default = [];
+        description = "users to run urxvtd for";
+      };
+      urxvtPackage = mkOption {
+        type = types.package;
+        default = pkgs.rxvt_unicode;
+        description = "urxvt package to use";
+      };
+    };
+  };
+
+  config = 
+    let
+      cfg = config.services.urxvtd;
+      users = cfg.users;
+      urxvt = cfg.urxvtPackage;
+      mkService = user: {
+        description = "urxvt terminal daemon";
+        wantedBy = [ "multi-user.target" ];
+        restartIfChanged = false;
+        serviceConfig = {
+          Restart = "always";
+          User = user;
+          Environment = "URXVT_PERL_LIB=${urxvt}/lib/urxvt/perl";
+          ExecStart = "${urxvt}/bin/urxvtd";
+        };
+      };
+    in
+      mkIf cfg.enable {
+        environment.systemPackages = [ urxvt ];
+        systemd.services = listToAttrs (map (u: { name = "${u}-urxvtd"; value = mkService u; }) users);
+      };
+}