From 0306ec4294f6d825ca65c7b0c98a80a3bced8fdf Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Sat, 24 Oct 2015 22:31:10 +0200
Subject: tv: lol display-manager

---
 tv/2configs/xserver/default.nix | 126 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 126 insertions(+)
 create mode 100644 tv/2configs/xserver/default.nix

(limited to 'tv/2configs/xserver/default.nix')

diff --git a/tv/2configs/xserver/default.nix b/tv/2configs/xserver/default.nix
new file mode 100644
index 000000000..b590fbd64
--- /dev/null
+++ b/tv/2configs/xserver/default.nix
@@ -0,0 +1,126 @@
+{ config, lib, pkgs, ... }@args:
+
+with lib;
+
+let
+  # TODO krebs.build.user
+  user = config.users.users.tv;
+
+  out = {
+    services.xserver.display = 11;
+    services.xserver.tty = 11;
+
+    services.xserver.synaptics = {
+      enable = true;
+      twoFingerScroll = true;
+      accelFactor = "0.035";
+    };
+
+    fonts.fonts = [
+      pkgs.xlibs.fontschumachermisc
+    ];
+
+    systemd.services.urxvtd = {
+      wantedBy = [ "multi-user.target" ];
+      reloadIfChanged = true;
+      serviceConfig = {
+        ExecReload = need-reload "urxvtd.service";
+        ExecStart = "${pkgs.rxvt_unicode}/bin/urxvtd";
+        Restart = "always";
+        RestartSec = "2s";
+        StartLimitBurst = 0;
+        User = user.name;
+      };
+    };
+
+    environment.systemPackages = [
+      pkgs.slock
+    ];
+
+    security.setuidPrograms = [
+      "slock"
+    ];
+
+    systemd.services.display-manager = mkForce {};
+
+    services.xserver.enable = true;
+    systemd.services.xmonad = {
+      wantedBy = [ "multi-user.target" ];
+      requires = [ "xserver.service" ];
+      serviceConfig = {
+        ExecStart = "${xmonad}/bin/xmonad";
+        User = user.name;
+        WorkingDirectory = user.home;
+      };
+    };
+
+    systemd.services.xserver = {
+      after = [
+        "systemd-udev-settle.service"
+        "local-fs.target"
+        "acpid.service"
+      ];
+      reloadIfChanged = true;
+      environment = xserver-environment;
+      serviceConfig = {
+        ExecReload = need-reload "xserver.service";
+        ExecStart = "${xserver}/bin/xserver";
+      };
+    };
+  };
+
+  xmonad = let
+    pkg = pkgs.haskellPackages.callPackage src {};
+    src = pkgs.runCommand "xmonad-package" {} ''
+      ${pkgs.cabal2nix}/bin/cabal2nix ${./xmonad} > $out
+    '';
+  in pkgs.writeScriptBin "xmonad" ''
+    #! /bin/sh
+    set -efu
+    export DISPLAY; DISPLAY=:${toString config.services.xserver.display}
+    export PATH; PATH=${makeSearchPath "bin" [
+      pkgs.rxvt_unicode
+    ]}
+    settle() {(
+      # Use PATH for a clean journal
+      command=''${1##*/}
+      PATH=''${1%/*}; export PATH
+      shift
+      until "$command" "$@"; do
+        ${pkgs.coreutils}/bin/sleep 1
+      done
+    )&}
+    settle ${pkgs.xorg.xhost}/bin/xhost +LOCAL:
+    settle ${pkgs.xorg.xrdb}/bin/xrdb -merge ${import ./Xresources.nix args}
+    settle ${pkgs.xorg.xsetroot}/bin/xsetroot -solid '#1c1c1c'
+    exec ${pkg}/bin/xmonad
+  '';
+
+  xserver-environment = {
+    XKB_BINDIR = "${pkgs.xorg.xkbcomp}/bin"; # Needed for the Xkb extension.
+    XORG_DRI_DRIVER_PATH = "/run/opengl-driver/lib/dri"; # !!! Depends on the driver selected at runtime.
+    LD_LIBRARY_PATH = concatStringsSep ":" (
+      [ "${pkgs.xorg.libX11}/lib" "${pkgs.xorg.libXext}/lib" ]
+      ++ concatLists (catAttrs "libPath" config.services.xserver.drivers));
+  };
+      
+  xserver = pkgs.writeScriptBin "xserver" ''
+    #! /bin/sh
+    set -efu
+    exec ${pkgs.xorg.xorgserver}/bin/X \
+        :${toString config.services.xserver.display} \
+        vt${toString config.services.xserver.tty} \
+        -config ${import ./xserver.conf.nix args} \
+        -logfile /var/log/X.${toString config.services.xserver.display}.log \
+        -nolisten tcp \
+        -xkbdir ${pkgs.xkeyboard_config}/etc/X11/xkb \
+  '';
+
+  need-reload = s: let
+    pkg = pkgs.writeScriptBin "need-reload" ''
+      #! /bin/sh
+      echo "$*"
+    '';
+  in "${pkg}/bin/need-reload ${s}";
+
+in out
-- 
cgit v1.2.3


From 6bdcab40b4e51f113ae30903152adcf778f33e53 Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Sat, 24 Oct 2015 22:36:24 +0200
Subject: tv xmonad: PATH += su (setuid-wrappers)

---
 tv/2configs/xserver/default.nix | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

(limited to 'tv/2configs/xserver/default.nix')

diff --git a/tv/2configs/xserver/default.nix b/tv/2configs/xserver/default.nix
index b590fbd64..5d3372609 100644
--- a/tv/2configs/xserver/default.nix
+++ b/tv/2configs/xserver/default.nix
@@ -80,7 +80,7 @@ let
     export DISPLAY; DISPLAY=:${toString config.services.xserver.display}
     export PATH; PATH=${makeSearchPath "bin" [
       pkgs.rxvt_unicode
-    ]}
+    ]}:/var/setuid-wrappers
     settle() {(
       # Use PATH for a clean journal
       command=''${1##*/}
-- 
cgit v1.2.3


From 2cf33f24be9de76d0a2d5818818b9826bf05a996 Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Sun, 25 Oct 2015 02:06:37 +0100
Subject: tv xmonad service: save state on shutdown

---
 tv/2configs/xserver/default.nix | 39 ++++++++++++++++++++++++++++-----------
 1 file changed, 28 insertions(+), 11 deletions(-)

(limited to 'tv/2configs/xserver/default.nix')

diff --git a/tv/2configs/xserver/default.nix b/tv/2configs/xserver/default.nix
index 5d3372609..9e20bda18 100644
--- a/tv/2configs/xserver/default.nix
+++ b/tv/2configs/xserver/default.nix
@@ -44,11 +44,14 @@ let
     systemd.services.display-manager = mkForce {};
 
     services.xserver.enable = true;
+
     systemd.services.xmonad = {
       wantedBy = [ "multi-user.target" ];
       requires = [ "xserver.service" ];
+      environment = xmonad-environment;
       serviceConfig = {
-        ExecStart = "${xmonad}/bin/xmonad";
+        ExecStart = "${xmonad-start}/bin/xmonad";
+        ExecStop = "${xmonad-stop}/bin/xmonad-stop";
         User = user.name;
         WorkingDirectory = user.home;
       };
@@ -69,15 +72,19 @@ let
     };
   };
 
-  xmonad = let
-    pkg = pkgs.haskellPackages.callPackage src {};
-    src = pkgs.runCommand "xmonad-package" {} ''
-      ${pkgs.cabal2nix}/bin/cabal2nix ${./xmonad} > $out
-    '';
-  in pkgs.writeScriptBin "xmonad" ''
-    #! /bin/sh
+  xmonad-pkg = pkgs.haskellPackages.callPackage xmonad-src {};
+  xmonad-src = pkgs.runCommand "xmonad-package" {} ''
+    ${pkgs.cabal2nix}/bin/cabal2nix ${./xmonad} > $out
+  '';
+
+  xmonad-environment = {
+    DISPLAY = ":${toString config.services.xserver.display}";
+    XMONAD_STATE = "/tmp/xmonad.state";
+  };
+
+  xmonad-start = pkgs.writeScriptBin "xmonad" ''
+    #! ${pkgs.bash}/bin/bash
     set -efu
-    export DISPLAY; DISPLAY=:${toString config.services.xserver.display}
     export PATH; PATH=${makeSearchPath "bin" [
       pkgs.rxvt_unicode
     ]}:/var/setuid-wrappers
@@ -93,7 +100,17 @@ let
     settle ${pkgs.xorg.xhost}/bin/xhost +LOCAL:
     settle ${pkgs.xorg.xrdb}/bin/xrdb -merge ${import ./Xresources.nix args}
     settle ${pkgs.xorg.xsetroot}/bin/xsetroot -solid '#1c1c1c'
-    exec ${pkg}/bin/xmonad
+    if test -e "$XMONAD_STATE"; then
+      IFS=''$'\n'
+      exec ${xmonad-pkg}/bin/xmonad --resume $(< "$XMONAD_STATE")
+    else
+      exec ${xmonad-pkg}/bin/xmonad
+    fi
+  '';
+
+  xmonad-stop = pkgs.writeScriptBin "xmonad-stop" ''
+    #! /bin/sh
+    exec ${xmonad-pkg}/bin/xmonad --shutdown
   '';
 
   xserver-environment = {
@@ -103,7 +120,7 @@ let
       [ "${pkgs.xorg.libX11}/lib" "${pkgs.xorg.libXext}/lib" ]
       ++ concatLists (catAttrs "libPath" config.services.xserver.drivers));
   };
-      
+
   xserver = pkgs.writeScriptBin "xserver" ''
     #! /bin/sh
     set -efu
-- 
cgit v1.2.3


From e281271239289a266777d0b429e604ec9aeaed41 Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Sun, 25 Oct 2015 02:32:19 +0100
Subject: {tv cfgs => krebs pkgs} writeNixFromCabal

---
 tv/2configs/xserver/default.nix | 4 +---
 1 file changed, 1 insertion(+), 3 deletions(-)

(limited to 'tv/2configs/xserver/default.nix')

diff --git a/tv/2configs/xserver/default.nix b/tv/2configs/xserver/default.nix
index 9e20bda18..facdf6df2 100644
--- a/tv/2configs/xserver/default.nix
+++ b/tv/2configs/xserver/default.nix
@@ -73,9 +73,7 @@ let
   };
 
   xmonad-pkg = pkgs.haskellPackages.callPackage xmonad-src {};
-  xmonad-src = pkgs.runCommand "xmonad-package" {} ''
-    ${pkgs.cabal2nix}/bin/cabal2nix ${./xmonad} > $out
-  '';
+  xmonad-src = pkgs.writeNixFromCabal "xmonad.nix" ./xmonad;
 
   xmonad-environment = {
     DISPLAY = ":${toString config.services.xserver.display}";
-- 
cgit v1.2.3


From 39236213abc668d35fab45e6bb747f11862e992d Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Sun, 25 Oct 2015 12:21:46 +0100
Subject: tv xmonad: read initial workspaces from file

---
 tv/2configs/xserver/default.nix | 13 +++++++++++++
 1 file changed, 13 insertions(+)

(limited to 'tv/2configs/xserver/default.nix')

diff --git a/tv/2configs/xserver/default.nix b/tv/2configs/xserver/default.nix
index facdf6df2..c5cffbb30 100644
--- a/tv/2configs/xserver/default.nix
+++ b/tv/2configs/xserver/default.nix
@@ -78,6 +78,19 @@ let
   xmonad-environment = {
     DISPLAY = ":${toString config.services.xserver.display}";
     XMONAD_STATE = "/tmp/xmonad.state";
+
+    # XXX JSON is close enough :)
+    XMONAD_WORKSPACES0_FILE = pkgs.writeText "xmonad.workspaces0" (toJSON [
+      "Dashboard" # we start here
+      "23"
+      "cr"
+      "ff"
+      "hack"
+      "im"
+      "mail"
+      "stockholm"
+      "za" "zj" "zs"
+    ]);
   };
 
   xmonad-start = pkgs.writeScriptBin "xmonad" ''
-- 
cgit v1.2.3