From cd6374e641420ade3603f0fd23fe9afac5c443bc Mon Sep 17 00:00:00 2001
From: tv <tv@shackspace.de>
Date: Wed, 8 Apr 2015 01:07:01 +0200
Subject: I Like To Move It

---
 modules/lass/urxvtd.nix | 68 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 modules/lass/urxvtd.nix

(limited to 'modules/lass/urxvtd.nix')

diff --git a/modules/lass/urxvtd.nix b/modules/lass/urxvtd.nix
new file mode 100644
index 000000000..a62e64a98
--- /dev/null
+++ b/modules/lass/urxvtd.nix
@@ -0,0 +1,68 @@
+{ config, lib, pkgs, ... }:
+
+let
+  inherit (import ../../lib { inherit pkgs; }) shell-escape;
+  inherit (pkgs) writeScript;
+in
+
+with builtins;
+with lib;
+
+{
+  options = {
+    services.urxvtd = {
+      enable = mkOption {
+        type = types.bool;
+        default = false;
+        description = "Enable urxvtd per user";
+      };
+      users = mkOption {
+        type = types.listOf types.string;
+        default = [];
+        description = "users to run urxvtd for";
+      };
+      urxvtPackage = mkOption {
+        type = types.package;
+        default = pkgs.rxvt_unicode;
+        description = "urxvt package to use";
+      };
+      xresources = mkOption {
+        type = types.string;
+        default = "";
+        description = ''
+          X server resources for urxvt.
+        '';
+      };
+    };
+  };
+
+  config = 
+    let
+      cfg = config.services.urxvtd;
+      users = cfg.users;
+      urxvt = cfg.urxvtPackage;
+      mkService = user: {
+        description = "urxvt terminal daemon";
+        wantedBy = [ "multi-user.target" ];
+        restartIfChanged = false;
+        path = [ pkgs.xlibs.xrdb ];
+        environment = {
+          DISPLAY = ":0";
+          URXVT_PERL_LIB = "${urxvt}/lib/urxvt/perl";
+        };
+        serviceConfig = {
+          Restart = "always";
+          User = user;
+          ExecStartPre = writeScript "urxvtd-prestart" ''
+            #!/bin/sh
+            echo ${shell-escape cfg.xresources} | xrdb -merge
+          '';
+          ExecStart = "${urxvt}/bin/urxvtd";
+        };
+      };
+    in
+      mkIf cfg.enable {
+        environment.systemPackages = [ urxvt ];
+        systemd.services = listToAttrs (map (u: { name = "${u}-urxvtd"; value = mkService u; }) users);
+      };
+}
-- 
cgit v1.2.3